Freqプロシジャでグラフを作成する(2) リスク差プロット、相対リスク比プロット

freqプロシジャでリスク差や相対リスク比を算出できますが、tableステートメントのplotsオプションを使用するとこれらを簡単にグラフとして表示できます。

リスク差プロット

plotsオプションにriskdiffplotを指定するとリスク差をドットプロットで表示してくれます。

riskdiffplotが使えるのはn*2*2の分割表です。

以下の集計結果をfreqプロシジャでリスク差プロットを作成してみます。

(男性)

(女性)

男性のリスク差は0.1 – 0.02 = 0.08
女性のリスク差は0.04 – 0.03 = 0.01

となります。

これをfreqプロシジャで計算してみましょう。

proc format;
   value cls 1="喫煙歴あり"
             2="喫煙歴なし";
   value adr 1="副作用あり"
　　　　  　 2="副作用なし";
   value sex 1="男"
             2="女";
run;

data test;
format sex sex. class cls. cat adr.;
input sex class cat count;
cards;
1 1 1 5 
1 1 2 45 
1 2 1 2 
1 2 2 98 
2 1 1 2 
2 1 2 48 
2 2 1 3 
2 2 2 97 
; 
run; 

proc freq data=test; 
tables sex*class*cat/ riskdiff plots=riskdiffplot;
weight count /zeros;
run;

実行結果

ASE: 帰無仮説の下での漸近標準誤差

エラーバーはデフォルトだとwald信頼区間を表示しています。信頼区間の種類を指定するにはclオプションで指定しましょう。

特に指定しない場合、リスク差プロットは列１（今回は副作用ありの列）をプロットしますが、columnオプションを2にすると列2（今回は副作用なしの列）をプロットします。

proc freq data=test; 
tables sex*class*cat/ riskdiff plots=riskdiffplot(column=2);
weight count /zeros;
run;

実行結果

相対リスクプロット

相対リスクをプロットするにはplotsオプションにrelriskplotを指定します。設定項目はriskdiffと同様です。プロットできるデータはn*2*2の分割表となります。またオッズ比も一緒にプロットしてくれます。

proc freq data=test; 
tables sex*class*cat/ relrisk plots=relriskplot; 
weight count /zeros; 
run;

実行結果（相対リスク）

実行結果（オッズ比）